按 U-Claw-海外化改造方案.md 与 范围决策记录.md 实施。这是 fork，不回上游： 海外版删掉的正是上游的中国市场默认值。 阶段 0 地基 - 下载源全部改国际：脚本/CI 61 处 + lockfile 880 条 npmmirror URL 归零 （lockfile 那 880 条是 npm 的 resolved 字段，脚本层参数化根本绕不过它） - 移除 install.ps1 里三个第三方 GitHub 加速代理，bundle 改直连 + SHA256 校验 （原来只检查"文件大于 1MB"就解压运行） - 技能内容与分发分离：skills/manifest.json 单一来源，install.sh 1170→658 行、 install.ps1 721→546 行，两者技能内容归零 实测原来是三份不一致：skills-cn 完整、install.sh 约 40%、install.ps1 约 17%， 且 7 个通用技能只有 U 盘版有 —— 一键安装的用户一个能用的技能都没有 - Node 版本三种（v22.14/16/22.1）统一，新建 NODE_VERSION 单一来源 - Config 页三份合一。portable/Config.html 用根相对路径调 API 却只从 file:// 打开， 保存功能已静默失效两个月；现缩为 120 行重定向壳 - 测试接入 CI（此前 node --test 无人运行，所有断言形同虚设） 阶段 1 双语可用 - 浏览器侧 i18n：JSON 为源、生成经典 script（file:// 下 fetch 本地 JSON 被拦） 语言跟盘走不跟机器走：启动器写 data/.openclaw/locale.js - 8 处硬编码 lang="zh-CN" 归零，data-i18n 覆盖 213 处，词条 en/zh 各 279 条 - B3 单框 Key：12 张模型卡 → 一个输入框，前缀识别 provider， 服务端 /api/test-key 发 1-token 请求实测，错误映射成人话 Key 填错到得知：从"直到对话失败"降到 ≤1 秒 - 区域格式 SG：DD/MM/YYYY、12 小时、S$、Asia/Singapore （ICU 在 en-SG 下把 SGD 渲染成裸 $，与美元无法区分，故自行拼 S$） - README 内容分叉而非翻译，§1.3 证据清单逐条清零 阶段 2 降门槛 - 启动逻辑上移 lib/start.mjs：Windows-Start.bat 220→28 行、 Mac-Start.command 235→33 行 修掉 Mac 侧两个 bug：控制台端口硬编码 18788（回落时打开死页）、 微信插件从未在 Mac 上安装 - U 盘根目录 23 → 3 个可点文件，其余进 advanced/ - 首启向导：语言 → 用途（7 角色，manifest 驱动）→ 密钥，答过不再问 - 三档界面，Simple 档隐藏一切技术名词 - 自动自愈：启动失败先自查自修，修不好导出脱敏诊断包 （Doctor 从"用户要知道去点的工具"变成后台机制） 阶段 3 技能库 - 19 个英文技能，planned 归零。sg-weather / sg-transport 的端点均实测过 - SkillHub 从 56 张手写第三方卡片改为 manifest 生成：703→125 行，中文归零 其他 - origin.json 收拢所有运行时地址，tests/origin.test.mjs 保证迁移不会漏 - portable/ 下用户可见中文归零（由断言保证） - 82 项测试 未验证（本机无 Windows / 无 pwsh）： - install.ps1、setup.ps1 约 210 行改动从未经 PowerShell 解析器 - 完整启动路径仅在假 node + 假 openclaw 上冒烟 - 8 个 .bat 的盘根推导仅静态断言 详见 U盘实测清单.md 受阻： - 隐藏黑窗口 —— 需代码签名证书（.vbs 已被 Windows 弃用，替代方案都要签名） - 场景卡 —— OpenClaw 上游 Dashboard 无预填 prompt 接口 - 官网 36 条 —— 上游 2026-04-14 拆到私有仓库，无权限
This commit is contained in:
200
portable/advanced/setup.bat
Normal file
200
portable/advanced/setup.bat
Normal file
@@ -0,0 +1,200 @@
|
||||
@echo off
|
||||
setlocal EnableDelayedExpansion
|
||||
chcp 65001 >nul 2>&1
|
||||
title U-Claw Portable Setup
|
||||
|
||||
for %%I in ("%~dp0..") do set "SCRIPT_DIR=%%~fI\"
|
||||
set "APP_DIR=%SCRIPT_DIR%app"
|
||||
set "CORE_DIR=%APP_DIR%\core"
|
||||
set "RUNTIME_DIR=%APP_DIR%\runtime"
|
||||
set "MIRROR=https://registry.npmjs.org"
|
||||
set "NODE_MIRROR=https://nodejs.org/dist"
|
||||
set "NODE_VERSION=v22.22.1"
|
||||
set "ALL_PLATFORMS=false"
|
||||
if "%~1"=="--all-platforms" set "ALL_PLATFORMS=true"
|
||||
|
||||
echo.
|
||||
echo ========================================
|
||||
echo U-Claw Portable Setup
|
||||
echo ========================================
|
||||
echo.
|
||||
|
||||
echo System: Windows x64
|
||||
echo.
|
||||
|
||||
REM ---- 1. Download Node.js (Current Platform - Windows) ----
|
||||
set "NODE_DIR_NAME=node-win-x64"
|
||||
set "NODE_TARGET=%RUNTIME_DIR%\%NODE_DIR_NAME%"
|
||||
|
||||
if exist "%NODE_TARGET%\node.exe" goto skip_node_download
|
||||
|
||||
echo [DOWNLOAD] Downloading Node.js %NODE_VERSION% (win-x64)...
|
||||
if not exist "%NODE_TARGET%" mkdir "%NODE_TARGET%" 2>nul
|
||||
|
||||
set "NODE_URL=%NODE_MIRROR%/%NODE_VERSION%/node-%NODE_VERSION%-win-x64.zip"
|
||||
echo URL: %NODE_URL%
|
||||
|
||||
set "TMP_ZIP=%TEMP%\node-win-x64-%RANDOM%.zip"
|
||||
curl -fSL "%NODE_URL%" -o "%TMP_ZIP%"
|
||||
|
||||
set "DOWNLOAD_OK=0"
|
||||
if %errorlevel% equ 0 set "DOWNLOAD_OK=1"
|
||||
|
||||
if "%DOWNLOAD_OK%"=="0" goto node_download_fail
|
||||
|
||||
echo Extracting...
|
||||
powershell -command "Expand-Archive -Path '%TMP_ZIP%' -DestinationPath '%TEMP%\node-extract' -Force" >nul 2>&1
|
||||
xcopy /s /e /q /y "%TEMP%\node-extract\node-%NODE_VERSION%-win-x64\*" "%NODE_TARGET%\" >nul
|
||||
rmdir /s /q "%TEMP%\node-extract" 2>nul
|
||||
del /f /q "%TMP_ZIP%" 2>nul
|
||||
|
||||
if not exist "%NODE_TARGET%\node.exe" goto node_download_fail
|
||||
|
||||
echo [OK] Node.js (win-x64) downloaded
|
||||
goto node_download_done
|
||||
|
||||
:node_download_fail
|
||||
echo [ERROR] Node.js download failed
|
||||
pause
|
||||
exit /b 1
|
||||
|
||||
:skip_node_download
|
||||
echo [OK] Node.js (win-x64) exists, skipping
|
||||
:node_download_done
|
||||
|
||||
REM ---- 1b. Download Node.js for Mac (only with --all-platforms) ----
|
||||
if not "%ALL_PLATFORMS%"=="true" goto skip_mac_download
|
||||
|
||||
for %%p in (arm64 x64) do (
|
||||
set "MAC_NODE_TARGET=%RUNTIME_DIR%\node-mac-%%p"
|
||||
if exist "!MAC_NODE_TARGET!\bin\node" (
|
||||
echo [OK] Node.js (mac-%%p) exists, skipping
|
||||
) else (
|
||||
echo [DOWNLOAD] Downloading Node.js %NODE_VERSION% (mac-%%p) for Mac support...
|
||||
if not exist "!MAC_NODE_TARGET!" mkdir "!MAC_NODE_TARGET!" 2>nul
|
||||
|
||||
set "MAC_NODE_URL=%NODE_MIRROR%/%NODE_VERSION%/node-%NODE_VERSION%-darwin-%%p.tar.gz"
|
||||
echo URL: !MAC_NODE_URL!
|
||||
|
||||
set "TMP_TAR=%TEMP%\node-mac-%%p-%RANDOM%.tar.gz"
|
||||
curl -fSL "!MAC_NODE_URL!" -o "!TMP_TAR!"
|
||||
|
||||
if !errorlevel! equ 0 (
|
||||
echo Extracting...
|
||||
powershell -command "tar -xzf '!TMP_TAR!' -C '!MAC_NODE_TARGET!' --strip-components 1" >nul 2>&1
|
||||
del /f /q "!TMP_TAR!" 2>nul
|
||||
|
||||
if exist "!MAC_NODE_TARGET!\bin\node" (
|
||||
echo [OK] Node.js (mac-%%p) downloaded
|
||||
) else (
|
||||
echo [WARNING] Mac runtime download failed (does not affect current platform)
|
||||
)
|
||||
) else (
|
||||
echo [WARNING] Mac runtime download failed (does not affect current platform)
|
||||
)
|
||||
)
|
||||
)
|
||||
|
||||
:skip_mac_download
|
||||
|
||||
set "NPM_BIN=%NODE_TARGET%\npm.cmd"
|
||||
|
||||
REM ---- 2. Install OpenClaw ----
|
||||
if exist "%CORE_DIR%\node_modules\openclaw" goto skip_openclaw_install
|
||||
|
||||
echo [INSTALL] Installing OpenClaw...
|
||||
if not exist "%CORE_DIR%" mkdir "%CORE_DIR%" 2>nul
|
||||
|
||||
REM Read pinned OpenClaw version from portable root, then repo root in dev checkouts
|
||||
set "OPENCLAW_VERSION_FILE=%~dp0OPENCLAW_VERSION"
|
||||
if not exist "%OPENCLAW_VERSION_FILE%" set "OPENCLAW_VERSION_FILE=%~dp0..\OPENCLAW_VERSION"
|
||||
set "OPENCLAW_VERSION=2026.4.29"
|
||||
if exist "%OPENCLAW_VERSION_FILE%" (
|
||||
for /f "usebackq delims=" %%v in ("%OPENCLAW_VERSION_FILE%") do set "OPENCLAW_VERSION=%%v"
|
||||
)
|
||||
REM Copy version file into portable/ so USB users can read it without repo root
|
||||
if exist "%OPENCLAW_VERSION_FILE%" (
|
||||
copy /y "%OPENCLAW_VERSION_FILE%" "%~dp0OPENCLAW_VERSION" >nul 2>&1
|
||||
)
|
||||
if not exist "%CORE_DIR%\package.json" (
|
||||
echo { "name": "u-claw-core", "version": "1.0.0", "private": true, "dependencies": { "openclaw": "%OPENCLAW_VERSION%" } } > "%CORE_DIR%\package.json"
|
||||
)
|
||||
|
||||
cd /d "%CORE_DIR%"
|
||||
call "%NPM_BIN%" install --prefix "%CORE_DIR%" --registry="%MIRROR%"
|
||||
|
||||
echo [OK] OpenClaw installed
|
||||
goto openclaw_install_done
|
||||
|
||||
:skip_openclaw_install
|
||||
echo [OK] OpenClaw exists, skipping
|
||||
:openclaw_install_done
|
||||
|
||||
REM ---- 3. Install QQ Plugin ----
|
||||
if exist "%CORE_DIR%\node_modules\@sliverp\qqbot" goto skip_qq_install
|
||||
|
||||
echo [INSTALL] Installing QQ Plugin...
|
||||
set "NPM_BIN=%NODE_TARGET%\npm.cmd"
|
||||
cd /d "%CORE_DIR%"
|
||||
call "%NPM_BIN%" install @sliverp/qqbot@latest --prefix "%CORE_DIR%" --registry="%MIRROR%" >nul 2>&1
|
||||
echo [OK] QQ Plugin installed
|
||||
goto qq_install_done
|
||||
|
||||
:skip_qq_install
|
||||
echo [OK] QQ Plugin exists, skipping
|
||||
:qq_install_done
|
||||
|
||||
set "QQ_DIR=%CORE_DIR%\node_modules\@sliverp\qqbot"
|
||||
if not exist "%QQ_DIR%" goto qq_build_done
|
||||
|
||||
if exist "%QQ_DIR%\dist\index.js" goto qq_build_cleanup
|
||||
|
||||
echo [BUILD] Building QQ Plugin runtime files...
|
||||
pushd "%QQ_DIR%"
|
||||
call "%NPM_BIN%" install --include=dev --registry="%MIRROR%" >nul 2>&1
|
||||
call "%NPM_BIN%" run build >nul 2>&1
|
||||
call "%NPM_BIN%" prune --omit=dev >nul 2>&1
|
||||
popd
|
||||
|
||||
:qq_build_cleanup
|
||||
if exist "%QQ_DIR%\node_modules\openclaw" rmdir /s /q "%QQ_DIR%\node_modules\openclaw" 2>nul
|
||||
if exist "%QQ_DIR%\dist\index.js" (
|
||||
echo [OK] QQ Plugin runtime files ready
|
||||
) else (
|
||||
echo [WARNING] QQ Plugin dist\index.js is missing
|
||||
)
|
||||
:qq_build_done
|
||||
|
||||
REM ---- 4. Install skills from the manifest ----
|
||||
REM Content lives in ..\skills (see skills\README.md); this script carries none.
|
||||
set "SKILLS_TARGET=%CORE_DIR%\node_modules\openclaw\skills"
|
||||
set "SKILL_INSTALLER=%SCRIPT_DIR%lib\install-skills.mjs"
|
||||
if not exist "%SKILL_INSTALLER%" set "SKILL_INSTALLER=%SCRIPT_DIR%..\lib\install-skills.mjs"
|
||||
|
||||
if exist "%SKILL_INSTALLER%" if exist "%SKILLS_TARGET%" (
|
||||
echo [SKILLS] Installing skills...
|
||||
"%NODE_TARGET%\node.exe" "%SKILL_INSTALLER%" --target "%SKILLS_TARGET%" --locale en
|
||||
)
|
||||
|
||||
REM ---- Done ----
|
||||
echo.
|
||||
echo ========================================
|
||||
echo Setup Complete!
|
||||
echo ========================================
|
||||
echo.
|
||||
echo To start:
|
||||
echo Mac: bash START HERE - Mac.command
|
||||
echo Windows: Double-click START HERE - Windows.bat
|
||||
echo.
|
||||
echo Directory structure:
|
||||
echo app\core\ - OpenClaw + dependencies
|
||||
echo app\runtime\ - Node.js %NODE_VERSION%
|
||||
echo data\ - Auto-generated after first run
|
||||
echo.
|
||||
if "%ALL_PLATFORMS%"=="true" (
|
||||
echo Note: All platform runtimes downloaded, ready for cross-platform USB
|
||||
) else (
|
||||
echo Note: For cross-platform USB use setup.bat --all-platforms
|
||||
)
|
||||
echo.
|
||||
pause
|
||||
Reference in New Issue
Block a user